Dans le monde du SEO, nous sommes régulièrement confrontés à la manipulation de données à travers le bon vieux Excel ou le rafraîchissant Google Sheet. Pour vous aider à manipuler des données facilement sur Googlesheet, j’ai compilé quelques formules qui vont vous éviter de perdre beaucoup de temps.

Pour ceux qui sont plutôt Excel, je vous invite à découvrir ce magnifique fichier qui compile l’ensemble des formules : c’est par là !

1. Extraire un NDD d’une url en incluant HTTP(S) and www

LEFT(A2,FIND("/",A2,9)-1)
googlesheet-seo-1

2. Extraire un NDD d’une url en excluant HTTP(S)

MID(A2,SEARCH("://",A2)+3,SEARCH("/",A2,9)-SEARCH("://",A2)-3)
googlesheet-seo-2

3. Extraire le nom de domaine d’une URL n’incluant pas HTTP(S) et www

MID(SUBSTITUTE(A2,"www.",""),SEARCH(":",A2)+3,SEARCH("/",SUBSTITUTE(A2,"www.",""),9)-SEARCH(":",A2)-3)
googlesheet-seo-3

4. Extraire le nom du site web à partir d’une URL

LEFT(MID(SUBSTITUTE(A2,"www.",""),SEARCH("://",A2)+3,SEARCH("/",SUBSTITUTE(A2,"www.",""),9)
-SEARCH("://",A2)-3),FIND(".",MID(SUBSTITUTE(A2,"www.",""),SEARCH("://",A2)+3,SEARCH("/",SUBSTITUTE(A2,"www.",""),9)
-SEARCH("://",A2)-3))-1) 

5. Extraire le protocole uniquement à partir d’une URL

LEFT(A2,(FIND(":",A2)-1))

6. Extraire l’extension du nom de domaine d’une URL

MID(MID(SUBSTITUTE(IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")),"www.",""),SEARCH("://",IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")))+3,
SEARCH("/",SUBSTITUTE(IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")),"www.",""),9)
-SEARCH("://",IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")))-3),FIND(".",MID(SUBSTITUTE(IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")),"www.",""),
SEARCH("://",IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")))+3,SEARCH("/",SUBSTITUTE(IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")),"www.",""),9)
-SEARCH("://",IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")))-3)),LEN(MID(SUBSTITUTE(IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")),"www.",""),
SEARCH("://",IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")))+3,SEARCH("/",SUBSTITUTE(IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")),"www.",""),9)
-SEARCH("://",IF(RIGHT(A2,1)="/",A2,CONCAT(A2,"/")))-3)))

7. Identifier quelles urls se terminent par un slash ou non

IF(RIGHT(A2,1)="/","Ends with a trailing slash","Does not end with a trailing slash")



8. Extraire le chemin de l’url

RIGHT(A2,LEN(A2)-FIND("/",A2,FIND("/",A2)+2)+1)
googlesheet-seo-8

9. Extraire n’importe quel folder d’un groupe d’urls

(ici dans l’exemple il s’agit du 3ème folder)

IFERROR(LEFT(TRIM(MID(A2,FIND("#",SUBSTITUTE(A2,"/","#",5))+1,255)),FIND("/",TRIM(MID(A2,FIND("#",SUBSTITUTE(A2,"/","#",5))+1,255)))-1),TRIM(MID(A2,FIND("#",SUBSTITUTE(A2,"/","#",5))+1,255)))

10. Extraire tout ce qui se trouve après un paramètre dans une URL

RIGHT(A2,LEN(A2)-FIND("?",A2))

11. Extraire tout ce qui précède un paramètre dans une URL

IFERROR(LEFT(A2,FIND("?",A2)-1),"No parameter in URL")

12. Extrayez tout ce qui se trouve dans l’avant-dernier dossier

IF(ISNUMBER(SEARCH(".",SUBSTITUTE(TRIM(LEFT(RIGHT(SUBSTITUTE("/"&IF(RIGHT(A2,1)="/",LEFT(A2,LEN(A2)-1),A2),"/",REPT(" ",99)),2*99),999))," ","/"))),
"No folder available",SUBSTITUTE(TRIM(LEFT(RIGHT(SUBSTITUTE("/"&IF(RIGHT(A2,1)="/",LEFT(A2,LEN(A2)-1),A2),"/",REPT(" ",99)),2*99),999))," ","/"))